cfpresentation ColdFusion 9 Documentation

Description

Defines the look of a dynamic slide presentation and determines whether to write the presentation files to disk. The cfpresentation tag is the parent tag for one or more cfpresentationslide tags, where you define the content for the presentation, and the cfpresenter tags, which provide information about the people presenting the slides.

History

ColdFusion 9: Added format and destination attributes.

ColdFusion 8: Added this tag.

Syntax

<cfpresentation 
    title = "text string" 
    authPassword = "authentication password" 
    authUser = "authentication user name" 
    autoPlay = "yes|no" 
    backgroundColor = "hexadecimal color|HTML named color" 
    control = "normal|brief" 
    controlLocation = "right|left" 
    destination = "filepath" 
    directory = "pathname" 
    format = "ppt|html" 
    glowColor = "hexadecimal color|HTML named color" 
    initialTab = "outline|search|notes" 
    lightColor = "hexadecimal color|HTML named color" 
    loop = "yes|no" 
    overwrite = "yes|no" 
    primaryColor = "hexadecimal color|HTML named color" 
    proxyHost = "IP address or server name for proxy host" 
    proxyPassword = "password for the proxy host" 
    proxyPort = "port of the proxy host" 
    proxyUser = "user name for the proxy host" 
    shadowColor = "hexadecimal color|HTML named color" 
    showNotes = "yes|no" 
    showOutline = "yes|no" 
    showSearch = "yes|no" 
    textColor = "hexadecimal color|HTML named color" 
    userAgent = "HTTP user agent identifier"> 
    presentation content... 
</cfpresentation>

Note: You can specify this tag’s attributes in an attributeCollection attribute whose value is a structure. Specify the structure name in the attributeCollection attribute and use the tag’s attribute names as structure keys.

Attributes

Attribute	Req/Opt	Default	Description
`authPassword`	Optional		Sends a password to the target URL for Basic Authentication. Combined with `username` to form a base64 encoded string that is passed in the Authenticate header. Does not provide support for Integrated Windows, NTLM, or Kerberos authentication.
`authUser`	Optional		Sends a user name to the target URL for Basic Authentication. Combined with `password` to form a base64 encoded string that is passed in the Authenticate header. Does not provide support for Integrated Windows, NTLM, or Kerebos authentication.
`autoPlay`	Optional	`yes`	Specifies whether to play the presentation automatically: `yes`: the presentation automatically runs through the entire presentation at startup. `no`: the user must click the Play button to start the presentation and click the Next button to advance to the next slide in the presentation.
`backgroundColor`	Optional	727971	Background color of the presentation. The value is hexadecimal: use the form `"##xxxxxx"` or `"##xxxxxxxx"`, where x = 0–9 or A–F; use two number signs or none. Also, you can use a subset of HTML named colors listed in the section Named colors.
`control`	Optional	`normal`	Presentation control: `normal` `brief`
`controlLocation`	Optional	`right`	Specifies the location of the presentation control: `right` `left`
`destination`	Optional		Absolute file name or a file path relative to the CFM page. You can use this for both connect presentation and ppt presentations. Required if `format="html"`.
`directory`	Optional		Directory where the presentation is saved. This can be an absolute path or a path relative to the CFM page. Also, ColdFusion creates a subdirectory called data that contains: A SWF file for each slide srchdata.xml (which creates the search interface) vconfig.xml viewer.xml images, video clips, and SWF files referenced by the `cfpresentationslide` tags If you do not specify a directory, ColdFusion writes the files to a temp directory and runs the presentation in the client browser.
`format`	Optional		Specifies the file format for conversion: `ppt` converts html input provided in cfpresentationslide to a PowerPoint file. `html` converts ppt to an HTML presentation.
`glowColor`	Optional	35D334	Color used for glow effects on the buttons. The value is hexadecimal: use the form `"##xxxxxx"` or `"##xxxxxxxx"`, where x = 0–9 or A–F; use two number signs or none. Also, you can use a subset of HTML named colors listed in the section Named colors.
`initialTab`	Optional	`outline`	Specifies which tab displays on top when the presentation is run. This applies only when the `control` value is `normal`: `outline` `search` `notes`
`lightColor`	Optional	4E5D60	Light color used for light-and-shadow effects. The value is hexadecimal: use the form `"##xxxxxx"` or `"##xxxxxxxx"`, where x = 0–9 or A–F; use two number signs or none. Also, you can use a subset of HTML named colors listed in the section Named colors.
`loop`	Optional	`no`	Specifies whether the presentation runs in a loop: `yes`: the presentation restarts automatically after it ends. `no`: the user must click the Play button to restart the presentation.
`overwrite`	Optional	`yes`	Specifies whether files in the directory are overwritten. Valid only when the directory attribute is specified. `yes`: overwrites files if they are already present `no`: creates new files
`primaryColor`	Optional	6F8488	Primary color of the presentation. The value is hexadecimal: use the form `"##xxxxxx"` or `"##xxxxxxxx"`, where x = 0–9 or A–F; use two number signs or none. Also, you can use a subset of HTML named colors listed in the section Named colors.
`proxyHost`	Optional		Host name or IP address of a proxy server to which to send the request.
`proxyPassword`	Optional		Password required by the proxy server.
`proxyPort`	Optional	80	The port to connect to on the proxy server.
`proxyUser`	Optional		User name to provide to the proxy server.
`shadowColor`	Optional	000000	Shadow color used for light-and-shadow effects. The value is hexadecimal: use the form `"##xxxxxx"` or `"##xxxxxxxx"`, where x = 0–9 or A–F; use two number signs or none. Also, you can use a subset of HTML named colors listed in the section Named colors.
`showNotes`	Optional	`no`	Specifies whether the Notes tab is present in the presentation control panel: `yes` `no`
`showOutline`	Optional	`yes`	Specifies whether the Outline is present in the presentation control panel: `yes` `no`
`showSearch`	Optional	`yes`	Specifies whether the Search tab is present in the presentation control panel: `yes` `no`
`textColor`	Optional	FFFFFF	Color for all the text in the presentation user interface. The value is hexadecimal: use the form `"##xxxxxx"` or `"##xxxxxxxx"`, where x = 0–9 or A–F; use two number signs or none. Also, you can use a subset of HTML named colors listed in the section Named colors.
`title`	Required		Title of the presentation
`userAgent`	Optional	ColdFusion	Text to put in the HTTP User-Agent request header field. Used to identify the request client software.

Usage

Use the cfpresentation tag to create the container for a slide presentation. You can define the position and appearance of the presentation controls, the background color, and the text for the presentation. Also, use this tag to determine whether to write the presentation to files or to run it directly in the client browser.

The settings in the cfpresentation tag do not affect the appearance of the content defined in the cfpresentationslide tags.

destination attribute

Use the following syntax to specify an in-memory file, which is not written to disk in the destination attribute. In-memory files speed processing of transient data.

ram:///filepath

The filepath can include directories, for example ram:///petStore/presentations/quarterlyresults.html. Create the directories in the path before you specify the file. For more information on using in-memory files, see Optimizing transient files in the Developing ColdFusion Applications.

Named colors

The cfpresentation tag supports the following named colors for use with the backgroundColor, glowColor, lightColor, primaryColor, shadowColor, and textColor attributes:

Named color	Hexadecimal value
`red`	FF0000
`green`	008000
`blue`	0000FF
`black`	000000
`white`	FFFFFF
`yellow`	FFFF00
`gray`	808080
`darkgray`	A9A9A9
`lightgray`	D3D3D3
`cyan`	00FFFF
`magenta`	FF00FF
`orange`	FFA500
`pink`	FFC0CB

Example

<!--- This example shows how to create a slide presentation from ---> 
<!--- an HTML file and from HTML code on the CFM page and write ---> 
<!--- the presentation files to a directory called myPresentation, ---> 
<!--- which is relative to the CFM page. ---> 
<cfpresentation title="Sales Presentation" directory="myPresenation"> 
    <cfpresenter name="Shyam" title="Vice President" email="shyam@somecompany.com" image="shyam.jpg"> 
    <cfpresenter name="Ram" title="Sr. Vice President" email="ram@somecompany.com"> 
 
<!--- The following code creates a slide from an HTML file ---> 
<!--- located on the ColdFusion server. ---> 
    <cfpresentationslide src="introduction.htm" title="Introduction" presenter="Shyam" 
        audio="myAudio.mp3" duration="36"/> 
 
<!--- The following code creates a slide from HTML code in the CFM file. ---> 
    <cfpresentationslide> 
        <h3>Sales</h3> 
        <ul> 
            <li>Overview</li> 
            <li>Q1 Sales Figures</li> 
            <li>Projected Sales</li> 
            <li>Competition</li> 
            <li>Advantages</li> 
            <li>Long Term Growth</li> 
        </ul> 
    </cfpresentationslide> 
 
<!--- The following code creates a slide from HTML and CFML code. ---> 
    <cfpresentationslide Title="Q1 Sales Figures" duration="14" presenter="Ram" 
            audio="myAudio2.mp3"> 
        <h3>Q1 Sales Figures</h3> 
        <cfchart format="png" showborder="yes" chartheight="250" chartwidth="300" 
            pieslicestyle="sliced"> 
        <cfchartseries type="pie"> 
            <cfchartdata item="Europe" value="9"> 
            <cfchartdata item="Asia" value="20"> 
            <cfchartdata item="North America" value="50"> 
            <cfchartdata item="South America" value="21"> 
        </cfchartseries> 
        </cfchart> 
    </cfpresentationslide> 
</cfpresentation>

cfpresentation